The Anchorage

Personal website of Gregory K. Maxey, Commander USN (Retired)

• Quarterdeck
• What's New
• Microsoft Word Tips
• Consulting
• Chain Locker
• Lucky Bag
• Contact
• Search

Do you have ad-blocking software enabled? While I respect your right to do so, your donations and the minimal advertisements on this site help to defray internet and other costs of providing this content. Please consider excluding this website from blocking or turning off the blocker while browsing this site.

The purpose of this Microsoft Word Help & Microsoft Word Tips page is to demonstrate an unexpected (buggy) behavior in Word when you attempt VBA Find operations within in a defined bookmark range.  Special thanks to Word MVPs Jay Freeman and Tony Jollans for recalling to my memory this problem and the steps necessary to work around it.

The Problem:

To illustrate the problem, open a new Word document and type the following text:

Select and bookmark the first, third, and last instance of "Test" using bookmarks A, B and C as shown below.

Now run the following macro. Here we have declared a range and a counter variable. We first set the range = to the bookmark "A" range and perform a find operation using the defined range and search term. Next we repeat the find operation using the bookmark "B" range and finally using the bookmark "C" range. In each case we expect to find the defined search text one time.

Sub FindInBookMarkRange()
Dim oRng As Word.Range
Dim i As Long
  Set oRng = ActiveDocument.Bookmarks("A").Range
  With oRng.Find
    .Text = "Test"
    While .Execute
      i = i + 1
    Wend
  End With
  MsgBox "Found " & i & " times."
  i = 0
  Set oRng = ActiveDocument.Bookmarks("B").Range
  With oRng.Find
    .Text = "Test"
    While .Execute
      i = i + 1
    Wend
  End With  
  MsgBox "Found " & i & " times."
  i = 0
  Set oRng = ActiveDocument.Bookmarks("C").Range
  With oRng.Find
    .Text = "Test"
    While .Execute
      i = 1 + 1
    Wend
  End With  
  MsgBox "Found " & i & " times."
lbl_Exit:
  Exit Sub
End Sub

See: Installing Macros for instructions on how to set up and use the macros provided in this Microsoft Word Help & Microsoft Word Tips page.

Needless to say the results are not as you would anticipate or expect.

The workaround:

I attempt to fully explain this and other fickle behavior when using the VBA Find .property in my Word's Fickle VBA Find .Property tips page. Please visit that page if you need a complete  review.  The behaviors influencing the results returned above are:

• You can find things "in" the defined search range, but you can't find the defined search range.
• The search range is "always" a dynamic range, regardless of how it is defined..

You can overcome the first issue and take advantage of the second issue by collapsing the defined search range to its beginning.

• After each Set statement in the code, add the line oRng.Collapse wdCollapseStart.
• Word now finds and counts the search term in the defined bookmark range and all other occurrences until it reaches the end of the document.

You can overcome the second by processing only found search terms that are contained within the defined bookmark range.

• Change each While .Execute statement by adding the appropriate conditional statement "And oRng.InRange(ActiveDocument.Bookmarks("*").Range)" * = A, B, or C as appropriate.
• Word now finds and counts each instance of the find term with the defined bookmark range but when the first instance outside the defined bookmark range is found (and evaluated as outside the defined range), the While ... Wend condition is not met. The found instance is not counted and the no other instances are found.

Run the modified code shown below to see the results displayed as expected.

Sub FindInBookMarkRangeII()
Dim oRng As Word.Range
Dim i As Long
  Set oRng = ActiveDocument.Bookmarks("A").Range
  'Collapse the range.
  oRng.Collapse wdCollapseStart
  With oRng.Find
    .Text = "Test"
    'Process (count) only instances found in defined search range.
    While .Execute And oRng.InRange(ActiveDocument.Bookmarks("A").Range)
      i = i + 1
    Wend
  End With
  MsgBox "Found " & i & " time."
  i = 0
  Set oRng = ActiveDocument.Bookmarks("B").Range
  oRng.Collapse wdCollapseStart
  With oRng.Find
    .Text = "Test"
    While .Execute And oRng.InRange(ActiveDocument.Bookmarks("B").Range)
      i = i + 1
    Wend
  End With
  MsgBox "Found " & i & " time."
  i = 0
  Set oRng = ActiveDocument.Bookmarks("C").Range
  oRng.Collapse wdCollapseStart
  With oRng.Find
    .Text = "Test"
    While .Execute And oRng.InRange(ActiveDocument.Bookmarks("C").Range)
      i = i + 1
    Wend
  End With
  MsgBox "Found " & i & " time."
lbl_Exit:
  Exit Sub
End Sub

That's it! I hope you have found this tips page useful and informative.

This page was last updated on March 31, 2021

Website Privacy Statement

Back to top    Back to Word Tips