Toggle Data Display

This Microsoft Word Tips & Microsoft Word Help page provides a couple of solutions to the frequently asked question, "How do I prevent the placeholder text in uncompleted content controls from printing?" The solutions provided are a result of collaborative effort with MVP Jay Freedman.

The problem can occur often. You prepare a form and send it out for completion. Users complete part of the form and leave some of the content controls uncompleted. When the form is returned and printed the placeholder text in the uncompleted content controls are printed. This results in an unsightly finished form.

Representation of a printed document with bubble added for emphasis

Unfortunately there isn't a simple solution. There is no option in Word to exclude printing placeholder text, and without an intensive form validation process, you can't make the user fill out each field.

Each of the automated solutions provided require VBA which means the template and form documents must be macro enabled (i.e., .dotm and .docm extensions).

Method I - Detect Events/Intercept Commands/Modify Style

The first method employs the application event "DocumentBeforePrint," repurposed Print commands and a temporary modification of the placeholder text style.

Placeholder text, like most text in Word, is defined by a style. If you temporarily set the placeholder text style font property .Hidden to true, set the application options .PrintHiddenText property to false and print the document the placeholder text will not be printed. This can of course be done manually if you have a willing group of form users, but an automated process requires a VBA solution.

Open Word, open the VB Editor (VBE) and open the Normal project.
Using the VBE Insert menu, insert a class module and a standard module in the Normal project. Rename the class module "clsPrint." Rename the standard module any meaningful name. I used modPrint.

Notes:
1. The Normal project is project associated with the Normal template. It is global and always loaded.

2. The method is developed for Word 2010, but includes all necessary code for Word 2007 users. Some elements (e.g., the class module) is not required for Word 2007.

Paste the following code in the class module.

VBA Script:

Copy to clipboard

Option Explicit
Private WithEvents oWordApp As Word.Application
Private Sub Class_Initialize()
 Set oWordApp = Word.Application
lbl_Exit:
  Exit Sub
End Sub

Private Sub oWordApp_DocumentBeforePrint(ByVal oDoc As Document, Cancel As Boolean)
Dim bOption As Boolean
  If Not bQuickPrint Then
    'Store current user option setting
    bOption = Options.PrintHiddenText
    'Turn off printing hidden text
    Options.PrintHiddenText = False
    'Modify the placeholder text style
    ActiveDocument.Styles("Placeholder Text").Font.Hidden = True
    'Execute the print command
    CommandBars.ExecuteMso "PrintPreviewAndPrint"
    'Pause to allow printer to spool document. Then undo style modification
    Application.OnTime Now + TimeValue("00:00:05"), "RestorePlaceholders"
    'Restore user option
    Options.PrintHiddenText = bOption
  End If
lbl_Exit:
  Exit Sub
End Sub

Paste the following code in the standard module:

VBA Script:

Copy to clipboard

Option Explicit
Private session_clsPrint As clsPrint
Public bQuickPrint As Boolean
Private bOption as Boolean

Sub AutoExec()
 'Initialize variable and class (Word 2010 only) when Word starts
 bQuickPrint = False
 If Application.Version > 12.0 Then
   Set session_clsPrint = New clsPrint
 End If
lbl_Exit:
  Exit Sub
End Sub

Sub RestorePlaceholders()
   'Delayed call from class
   ActiveDocument.Styles("Placeholder Text").Font.Hidden = False
lbl_Exit:
  Exit Sub
End Sub

Sub FilePrint()
  'Intercepts the Word 2007 Menu>Print>Print command
  bOption = Options.PrintHiddenText
  Options.PrintHiddenText = False
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = True
  Dialogs(wdDialogFilePrint).Show
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = False
  Options.PrintHiddenText = bOption
End Sub

Sub FilePrintDefault()
  'Intercepts the Word 2007/2010 Quick Print commands
  bOption = Options.PrintHiddenText
  'Prevent double printing
  bQuickPrint = True
  Options.PrintHiddenText = False
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = True
  ActiveDocument.PrintOut Background:=False
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = False
  bQuickPrint = False
  Options.PrintHiddenText = bOption
lbl_Exit:
  Exit Sub
End Sub

Sub PrintPreviewEditMode()
  'Intercepts the Word 2010 Print Preview Edit Mode
  'There is no apparent method to intercept and modify the print preview displayed in the Word 2010 backstage view
  bOption = Options.PrintHiddenText
  Options.PrintHiddenText = False
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = True
  ActiveDocument.PrintPreview
  Options.PrintHiddenText = bOption
lbl_Exit:
  Exit Sub
End Sub

Sub FilePrintPreview()
  'Intercepts the Word 2007 Print Preview command
  bOption = Options.PrintHiddenText
  Options.PrintHiddenText = False
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = True
  ActiveDocument.PrintPreview
  Options.PrintHiddenText = bOption
lbl_Exit:
  Exit Sub
End Sub

Sub ClosePreview()
  ActiveDocument.Styles("Placeholder Text").Font.Hidden = False
  ActiveDocument.ClosePrintPreview
lbl_Exit:
  Exit Sub
End Sub

Save the template project. Close the VBE. Close and restart Word.
Try it out on documents with and without uncompleted content controls.

The following is an explanation of how the process more or less works:

The AutoExec macro runs automatically each time you start Word. It sets the initial variables and if the application is Word 2010 it initializes the variable session_clsPrint to an instance of the class module clsPrint. The Class_Initialize procedure in the class initializes the oWordApp variable to the Word application object.
When a Word 2010 user clicks File>Print>Print that action triggers the clsPrint oWordApp_DocumentBeforePrint procedure. This procedure:

Stores the current option value
Ensures the "print hidden text" option is off
Set the the placeholder text style font "Hidden" property = True.
Calls the built-in Word "PrintPreviewAndPrint" command. This is the command executed by the backstage view Print button. Unlike most other user interface commands, this one can't be intercepted using the usual VBA method of naming a procedure the same as the command -- Thanks, Microsoft!).
After a defined 5 second delay the procedure calls the RestorePlaceholders procedure located in the standard module. The delay should provide ample time to let the print command finish spooling the document to the printer queue.
Restores options to stored setting

Note: If you often print large forms, you may want to increase the time. This delay is needed because changing the Hidden attribute immediately (in the end of the DocumentBeforePrint routine) would happen before the PrintPreviewAndPrint command runs (We are not sure why, but it just doesn't work).

When a Word 2007 user clicks the Word Menu>Print>Print command the procedure named "FilePrint" intercepts the built-in "FilePrint" command. The procedure performs functions similar to the event procedure described above. A delay, however, is not required.
The FilePrintDefault procedure intercepts the QuickPrint command in both Word 2007 and 2010. It functions similar to the FilePrint procedure
The remaining procedures intercept the named built-in commands to display the Print Preview screens.
The class and module procedures have no effect on documents that don't contain content controls, or documents in which all content controls are completed by the user.

Note: Jay and I have not found a method to intercept and alter the Print Preview in the Word 2010 backstage view. Placeholder text in will continue to display in this view even though it will not actually be printed.

Method II - Detect Events/Intercept Commands/Modify Text

The second method, similar to the first, employs the application event "DocumentBeforePrint," repurposed Print commands and a temporary alteration of the placeholder text itself.

Placeholder text, is a bit peculiar. While it appears to be text, a content control's .PlaceholderText property is actually a Building Block object with a value. For a more in depth discussion see: 5 Curiosities about Placeholders in Word Content Controls (for developers). If we temporarily set the .PlaceholderText property to a single space " " before printing and restore the original text after printing the results will be similar to method I. The code is a bit more complicated and the only advantage is we don't tinker with user options or restrict printing of hidden text in general. The jury is still deliberating if there is any real advantage over either method, but for completeness, here it is:

Open Word, open the VBE and open the Normal project.
Using the VBE Insert menu, insert a class module and a standard module in the Normal project. Rename the class module "clsPrint." Rename the standard module any meaningful name. I used modPrint.

Note: If you have already created the modules using Method 1 then simply delete the existing content in the modules. Do not attempt to use both methods simultaneously.

Paste the following code in the class module.

VBA Script:

Copy to clipboard

Option Explicit
Private WithEvents oWordApp As Word.Application
Private Sub Class_Initialize()
  Set oWordApp = Word.Application
End Sub
Private Sub oWordApp_DocumentBeforePrint(ByVal oDoc As Document, Cancel As Boolean)
Dim bOption As Boolean
If Not bQuickPrint Then
  'Call procedures in the standard module to alter placeholder text
  modPrint.DimensionArray
  modPrint.Processor 2
  'Execute the print command
  CommandBars.ExecuteMso "PrintPreviewAndPrint"
  'Pause to allow printer to spool document. Then call procedure to restore placeholder
  Application.OnTime Now + TimeValue("00:00:05"), "modPrint.RestorePHT"
End If
End Sub

Paste the following code in the standard module:

VBA Script:

Copy to clipboard

Option Explicit
Private session_clsPrint As clsPrint
Private oRngStory As Word.Range
Private lngValidator As Long
Private oCC As ContentControl
Private oShp As Shape
Private arrPHT() As String
Private i As Long
Public Type CCCollection
  Count As Long
  bContainsCCs As Boolean
End Type
Dim bContainsCCs As Boolean
Public bQuickPrint As Boolean

Sub AutoExec()
 'Initialize variable and class when Word starts
 bQuickPrint = False
 If Application.Version > 12# Then
   Set session_clsPrint = New clsPrint
 End If
lbl_Exit:
  Exit Sub
End Sub

Sub DimensionArray()
  'Count CCs in document
  i = Processor(1).Count
  ReDim arrPHT(i)
lbl_Exit:
  Exit Sub
End Sub

Sub RestorePHT()
  'Called from clsPrint
  modPrint.Processor 3
lbl_Exit:
  Exit Sub
End Sub

Sub FilePrint()
  'Intercepts the Word 2007 Menu>Print>Print command
  'Call procedures alter placeholder text
  DimensionArray
  Processor 2
  Dialogs(wdDialogFilePrint).Show
  'Call procedures to restore placeholder text
  Processor 3
lbl_Exit:
  Exit Sub
End Sub

Sub FilePrintDefault()
  'Intercepts the Word 2007/2010 Quick Print commands
  'Call procedures alter placeholder text
  DimensionArray
  Processor 2
  'Print the document
  ActiveDocument.PrintOut
  'Call procedures to restore placeholder text
  Processor 3
lbl_Exit:
  Exit Sub
End Sub

Sub PrintPreviewEditMode()
  'Intercepts the Wor 2010 PrintPreviewEditMode command
  bContainsCCs = False
  DimensionArray
  If Processor(2).bContainsCCs = True Then
    bContainsCCs = True
  End If
  ActiveDocument.PrintPreview
  If bContainsCCs Then Application.StatusBar = "CC PHT modified"
lbl_Exit:
  Exit Sub
End Sub

Sub FilePrintPreview()
  'Intercepts the Word 2007 PrintPreview command
  bContainsCCs = False
  DimensionArray
  If Processor(2).bContainsCCs = True Then
    bContainsCCs = True
  End If
  ActiveDocument.PrintPreview
  If bContainsCCs Then Application.StatusBar = "CC PHT modified"
lbl_Exit:
  Exit Sub
End Sub

Sub ClosePreview()
  Processor 3
  ActiveDocument.ClosePrintPreview
lbl_Exit:
  Exit Sub
End Sub

Function Processor(ByRef lngAction As Long) As CCCollection
  Dim oCount As Long
  i = 0
  lngValidator = ActiveDocument.Sections(1).Headers(1).Range.StoryType
  For Each oRngStory In ActiveDocument.StoryRanges
    'Iterate through all linked stories
    Select Case oRngStory.StoryType
      Case 1 To 11
        Do
          For Each oCC In oRngStory.ContentControls
            Select Case lngAction
              Case 1
                oCount = oCount + 1
              Case 2
                oCount = oCount + 1
                'Store placeholder text
                arrPHT(i) = oCC.PlaceholderText
                'Set temporary placeholder text
                oCC.SetPlaceholderText , , " "
                i = i + 1
              Case 3
               If oCC.ShowingPlaceholderText Then
                 'Restore stored placeholder text
                 oCC.SetPlaceholderText , , arrPHT(i)
               End If
               i = i + 1
            End Select
          Next oCC
          Select Case oRngStory.StoryType
            Case 6, 7, 8, 9, 10, 11
              If oRngStory.ShapeRange.Count > 0 Then
                For Each oShp In oRngStory.ShapeRange
                  On Error GoTo Err_HasText
                  If oShp.TextFrame.HasText Then
                    For Each oCC In oShp.TextFrame.TextRange.ContentControls
                      Select Case lngAction
                        Case 1
                          oCount = oCount + 1
                        Case 2
                          'Store placeholder text
                          arrPHT(i) = oCC.PlaceholderText
                          'Set temporary placeholder text
                          oCC.SetPlaceholderText , , " "
                          i = i + 1
                        Case 3
                          If oCC.ShowingPlaceholderText Then
                           'Restore stored placeholder text
                           oCC.SetPlaceholderText , , arrPHT(i)
                          End If
                         i = i + 1
                      End Select
                    Next oCC
                  End If
                  On Error GoTo 0
Err_HasText_ReEntry:
                Next oShp
              End If
            Case Else
            'Do Nothing
          End Select
          'Get next linked story (if any)
          Set oRngStory = oRngStory.NextStoryRange
        Loop Until oRngStory Is Nothing
      Case Else
    End Select
  Next oRngStory
  Processor.Count = oCount
  If oCount > 0 Then
    Processor.bContainsCCs = True
  End If
  Exit Function
Err_HasText:
  Resume Err_HasText_ReEntry
End Function

Save the template project. Close the VBE. Close and restart Word.
Try it out on documents with and without uncompleted content controls.

The process and procedures are similar to Method I, instead of changing the placeholder text style, it:

Loops through the document storyranges to count the CCs and store the CC placeholder text values.
Sets each CC placeholder text value to a single space.
Prints/Print Previews the document.
Loops through the document storyranges to restore original placeholder text.

Method III - Document Content Control Events/Custom Placeholder Text

Method III employs an individual document template, the Document_ContentControlOnEnter & Document_ContentControlOnExit events and custom placeholder text applied dynamically as the user completes the form.

The template should be setup as illustrated in the example below:

Design Mode view

cc do not print pht 3

Open the VBE, open the templateProject, expand the Microsoft Word Objects folder.
Double click the ThisDocument class module. In right side code window, select the Document object.

VBE code pane

Select all existing code and paste in the following code:

VBA Script:

Copy to clipboard

Option Explicit
Private Sub Document_New()
  ActiveDocument.SelectContentControlsByTitle("Name").Item(1).Range.Select
lbl_Exit:
  Exit Sub
End Sub

Private Sub Document_Open()
  ActiveDocument.SelectContentControlsByTitle("Name").Item(1).Range.Select
lbl_Exit:
  Exit Sub
End Sub

Private Sub Document_ContentControlOnEnter(ByVal ContentControl As ContentControl)
Select Case ContentControl.Title
  Case "Name"
    ContentControl.SetPlaceholderText , , "Click and enter your name here."
  Case "Address"
    ContentControl.SetPlaceholderText , , "Click and enter your address here."
  Case "Phone Number"
    ContentControl.SetPlaceholderText , , "Click and enter your phone number here."
End Select
lbl_Exit:
  Exit Sub
End Sub

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
  If ContentControl.ShowingPlaceholderText = True Then
    ContentControl.SetPlaceholderText , , " "
  End If
lbl_Exit:
  Exit Sub
End Sub

Save and close the template and create a new document based on the template.

Unlike the previous methods, this method has no relationship with the application print processes. It simply uses the built-in document events to dynamically apply or remove a visible placeholder text as the user navigates the form.

When the form is initially created (new document) or opened, the CC titled "Name" is selected for user input.
If the exits the CC without providing an input, the placeholder text is set to a single space.
When the user enters a CC, if that CC is showing placeholder text (even a non-visible single space), a custom visible placeholder text prompt is presented.

Note: This method is the least robust since it is possible that a user enters a CC displaying the visible placeholder text and then prints the document without first exiting the CC. You, or your users, must be sure to physically "exit" any uncompleted document CC.

Conclusion

If properly applied each of the three methods will result in a more appealing printed form.

That's it! I hope you have found this tips page useful and informative.

	Enter your search terms Submit search form
	Web gregmaxey.mvps.org

Content Controls – Don't Print Placeholder Text(A Microsoft Word Help & Tip page by Gregory K. Maxey)

Method I - Detect Events/Intercept Commands/Modify Style

Method II - Detect Events/Intercept Commands/Modify Text

Method III - Document Content Control Events/Custom Placeholder Text

Conclusion

Content Controls – Don't Print Placeholder Text
(A Microsoft Word Help & Tip page by Gregory K. Maxey)